<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Archive::Zip::BufferedFileHandle;

# File handle that uses a string internally and can seek
# This is given as a demo for getting a zip file written
# to a string.
# I probably should just use IO::Scalar instead.
# Ned Konz, March 2000

use strict;
use IO::File;
use Carp;

use vars qw{$VERSION};

BEGIN {
    $VERSION = '1.68';
    $VERSION = eval $VERSION;
}

sub new {
    my $class = shift || __PACKAGE__;
    $class = ref($class) || $class;
    my $self = bless(
        {
            content  =&gt; '',
            position =&gt; 0,
            size     =&gt; 0
        },
        $class
    );
    return $self;
}

# Utility method to read entire file
sub readFromFile {
    my $self     = shift;
    my $fileName = shift;
    my $fh       = IO::File-&gt;new($fileName, "r");
    CORE::binmode($fh);
    if (!$fh) {
        Carp::carp("Can't open $fileName: $!\n");
        return undef;
    }
    local $/ = undef;
    $self-&gt;{content} = &lt;$fh&gt;;
    $self-&gt;{size}    = length($self-&gt;{content});
    return $self;
}

sub contents {
    my $self = shift;
    if (@_) {
        $self-&gt;{content} = shift;
        $self-&gt;{size}    = length($self-&gt;{content});
    }
    return $self-&gt;{content};
}

sub binmode { 1 }

sub close { 1 }

sub opened { 1 }

sub eof {
    my $self = shift;
    return $self-&gt;{position} &gt;= $self-&gt;{size};
}

sub seek {
    my $self   = shift;
    my $pos    = shift;
    my $whence = shift;

    # SEEK_SET
    if ($whence == 0) { $self-&gt;{position} = $pos; }

    # SEEK_CUR
    elsif ($whence == 1) { $self-&gt;{position} += $pos; }

    # SEEK_END
    elsif ($whence == 2) { $self-&gt;{position} = $self-&gt;{size} + $pos; }
    else                 { return 0; }

    return 1;
}

sub tell { return shift-&gt;{position}; }

# Copy my data to given buffer
sub read {
    my $self = shift;
    my $buf  = \($_[0]);
    shift;
    my $len = shift;
    my $offset = shift || 0;

    $$buf = '' if not defined($$buf);
    my $bytesRead =
        ($self-&gt;{position} + $len &gt; $self-&gt;{size})
      ? ($self-&gt;{size} - $self-&gt;{position})
      : $len;
    substr($$buf, $offset, $bytesRead) =
      substr($self-&gt;{content}, $self-&gt;{position}, $bytesRead);
    $self-&gt;{position} += $bytesRead;
    return $bytesRead;
}

# Copy given buffer to me
sub write {
    my $self = shift;
    my $buf  = \($_[0]);
    shift;
    my $len = shift;
    my $offset = shift || 0;

    $$buf = '' if not defined($$buf);
    my $bufLen = length($$buf);
    my $bytesWritten =
      ($offset + $len &gt; $bufLen)
      ? $bufLen - $offset
      : $len;
    substr($self-&gt;{content}, $self-&gt;{position}, $bytesWritten) =
      substr($$buf, $offset, $bytesWritten);
    $self-&gt;{size} = length($self-&gt;{content});
    return $bytesWritten;
}

sub clearerr() { 1 }

1;
</pre></body></html>