<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package TAP::Parser::ResultFactory;

use strict;
use warnings;

use TAP::Parser::Result::Bailout ();
use TAP::Parser::Result::Comment ();
use TAP::Parser::Result::Plan    ();
use TAP::Parser::Result::Pragma  ();
use TAP::Parser::Result::Test    ();
use TAP::Parser::Result::Unknown ();
use TAP::Parser::Result::Version ();
use TAP::Parser::Result::YAML    ();

use base 'TAP::Object';

##############################################################################

=head1 NAME

TAP::Parser::ResultFactory - Factory for creating TAP::Parser output objects

=head1 SYNOPSIS

  use TAP::Parser::ResultFactory;
  my $token   = {...};
  my $factory = TAP::Parser::ResultFactory-&gt;new;
  my $result  = $factory-&gt;make_result( $token );

=head1 VERSION

Version 3.43

=cut

our $VERSION = '3.43';

=head2 DESCRIPTION

This is a simple factory class which returns a L&lt;TAP::Parser::Result&gt; subclass
representing the current bit of test data from TAP (usually a single line).
It is used primarily by L&lt;TAP::Parser::Grammar&gt;.  Unless you're subclassing,
you probably won't need to use this module directly.

=head2 METHODS

=head2 Class Methods

=head3 C&lt;new&gt;

Creates a new factory class.
I&lt;Note:&gt; You currently don't need to instantiate a factory in order to use it.

=head3 C&lt;make_result&gt;

Returns an instance the appropriate class for the test token passed in.

  my $result = TAP::Parser::ResultFactory-&gt;make_result($token);

Can also be called as an instance method.

=cut

sub make_result {
    my ( $proto, $token ) = @_;
    my $type = $token-&gt;{type};
    return $proto-&gt;class_for($type)-&gt;new($token);
}

=head3 C&lt;class_for&gt;

Takes one argument: C&lt;$type&gt;.  Returns the class for this $type, or C&lt;croak&gt;s
with an error.

=head3 C&lt;register_type&gt;

Takes two arguments: C&lt;$type&gt;, C&lt;$class&gt;

This lets you override an existing type with your own custom type, or register
a completely new type, eg:

  # create a custom result type:
  package MyResult;
  use strict;
  use base 'TAP::Parser::Result';

  # register with the factory:
  TAP::Parser::ResultFactory-&gt;register_type( 'my_type' =&gt; __PACKAGE__ );

  # use it:
  my $r = TAP::Parser::ResultFactory-&gt;( { type =&gt; 'my_type' } );

Your custom type should then be picked up automatically by the L&lt;TAP::Parser&gt;.

=cut

our %CLASS_FOR = (
	plan    =&gt; 'TAP::Parser::Result::Plan',
	pragma  =&gt; 'TAP::Parser::Result::Pragma',
	test    =&gt; 'TAP::Parser::Result::Test',
	comment =&gt; 'TAP::Parser::Result::Comment',
	bailout =&gt; 'TAP::Parser::Result::Bailout',
	version =&gt; 'TAP::Parser::Result::Version',
	unknown =&gt; 'TAP::Parser::Result::Unknown',
	yaml    =&gt; 'TAP::Parser::Result::YAML',
);

sub class_for {
    my ( $class, $type ) = @_;

    # return target class:
    return $CLASS_FOR{$type} if exists $CLASS_FOR{$type};

    # or complain:
    require Carp;
    Carp::croak("Could not determine class for result type '$type'");
}

sub register_type {
    my ( $class, $type, $rclass ) = @_;

    # register it blindly, assume they know what they're doing
    $CLASS_FOR{$type} = $rclass;
    return $class;
}

1;

=head1 SUBCLASSING

Please see L&lt;TAP::Parser/SUBCLASSING&gt; for a subclassing overview.

There are a few things to bear in mind when creating your own
C&lt;ResultFactory&gt;:

=over 4

=item 1

The factory itself is never instantiated (this I&lt;may&gt; change in the future).
This means that C&lt;_initialize&gt; is never called.

=item 2

C&lt;TAP::Parser::Result-E&lt;gt&gt;new&gt; is never called, $tokens are reblessed.
This I&lt;will&gt; change in a future version!

=item 3

L&lt;TAP::Parser::Result&gt; subclasses will register themselves with
L&lt;TAP::Parser::ResultFactory&gt; directly:

  package MyFooResult;
  TAP::Parser::ResultFactory-&gt;register_type( foo =&gt; __PACKAGE__ );

Of course, it's up to you to decide whether or not to ignore them.

=back

=head2 Example

  package MyResultFactory;

  use strict;

  use MyResult;

  use base 'TAP::Parser::ResultFactory';

  # force all results to be 'MyResult'
  sub class_for {
    return 'MyResult';
  }

  1;

=head1 SEE ALSO

L&lt;TAP::Parser&gt;,
L&lt;TAP::Parser::Result&gt;,
L&lt;TAP::Parser::Grammar&gt;

=cut
</pre></body></html>